***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 06, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAV20WS-AU A K 
.param
+vc0 = 2.372e-10	 vc1 = 5.027e-11		 vc2 = 8.267e-11		vc3 = 1.174e-1
+tc1 = 5.285e-2		 tc2 = 4.285e-2			 tc3 = 3.194e-3			tc4 = 3.194e-3
.func ir(v) {(vc0+vc1*v)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*v**vc3*(1.0+tc3*(temp-25)*exp(tc4*(temp-25))))}
d1 A K diode
g1 K A value = {ir(v(K,A))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 3.876e-9		   n = 1.904		  rs = 3.856e-1		 ikf = 2.183e-2
+ibv = 0.1e-3		 nbv = 1			  bv = 220
***** capacitance parameter *****
+cjo = 8.710e-13	   m = 7.385e-2		  vj = 9.251e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.100		 xti = 3
+trs1 = -1.001e-4	trs2 = 7.235e-6		tikf = 4e-3		
.ends BAV20WS-AU
*$
